'Visual Basic 2010 Class of Shared Members Shared Members
Namespace SharedMembersOfAClass
    Class Area
        Public Shared Function Rectangle(ByVal height As Double, _
                                         ByVal width As Double) As Double
            Return height * width
        End Function
        Public Shared Function Circle(ByVal radius As Double) As Double
            Return radius ^ 2 * Math.PI
        End Function
    End Class
End Namespace
Namespace SharedMembersOfAClass
    Module Client
        Public Sub Main()
            Console.WriteLine(Area.Rectangle(3, 4))
            Console.WriteLine(Area.Circle(1))
            '
            Console.ReadLine()
        End Sub
    End Module
End Namespace
Namespace SharedMembersOfAModule
    Module Area
        Public Function Rectangle(ByVal height As Double, _
                                  ByVal width As Double) As Double
            Return height * width
        End Function
        Public Function Circle(ByVal radius As Double) As Double
            Return radius ^ 2 * Math.PI
        End Function
    End Module
End Namespace
Namespace SharedMembersOfAModule
    Class Client
        Public Shared Sub Main()
            Console.WriteLine(Area.Rectangle(3, 4))
            Console.WriteLine(Area.Circle(1))
            '
            Console.ReadLine()
        End Sub
    End Class
End Namespace
Namespace ConstantsAreShared
    Class Area
        Public Shared Function Rectangle(ByVal height As Double, _
                                         ByVal width As Double) As Double
            Return height * width
        End Function
        Public Shared Function Circle(ByVal radius As Double) As Double
            Return radius ^ 2 * PI
        End Function
        Public Const PI As Double = Math.PI
    End Class
    Class Example3
        Public Shared Sub Main()
            Console.WriteLine(Area.Rectangle(3, 4))
            Console.WriteLine(Area.Circle(1))
            Console.WriteLine(Area.PI)
            '
            Console.ReadLine()
        End Sub
    End Class
End Namespace
Namespace ClassVariables
    Class [Class]
        Public Sub New(ByVal instanceValue As Integer, _
                       ByVal classValue As Integer)
            m_InstanceValue = instanceValue
            m_ClassValue = classValue
        End Sub
        Private m_InstanceValue As Integer
        Private Shared m_ClassValue As Integer
        Public Overrides Function ToString() As String
            ToString = "InstanceValue : " & m_InstanceValue & " / " & _
                        "ClassValue : " & m_ClassValue
        End Function
    End Class
End Namespace
Namespace ClassVariables
    Class Client
        Public Shared Sub Main()
            Dim object1 As [Class] = New [Class](1, 10)
            Console.WriteLine(object1.ToString())
            '
            Dim object2 As [Class] = New [Class](2, 20)
            Console.WriteLine(object2.ToString())
            '
            Console.WriteLine(object1.ToString())
            '
            Console.ReadLine()
        End Sub
    End Class
End Namespace
Namespace SharedConstructors
    Class Class1
        Shared Sub New()
            Console.WriteLine("Class1 : Shared Sub New()")
        End Sub
        Public Sub New()
            Console.WriteLine("Class1 : Public Sub New()")
        End Sub
        Public Shared Sub Test()
            Console.WriteLine("Class1 : Public Sub Test()")
        End Sub
    End Class
    Class Client1
        Public Shared Sub Main()
            Dim object1 As Class1 = New Class1             ' (1)
            '
            Console.ReadLine()
        End Sub
    End Class
End Namespace
Namespace SharedConstructors
    Class Class2 : Inherits Class1
        Shared Sub New()
            Console.WriteLine("Class2 : Shared Sub New()")
        End Sub
        Public Sub New()
            MyBase.New()                                   ' (2)
            Console.WriteLine("Class2 : Public Sub New()")
        End Sub
    End Class
    Class Client2
        Public Shared Sub Main()
            Dim object2 As Class2 = New Class2
            '
            Console.ReadLine()
        End Sub
    End Class
End Namespace
Namespace SharedConstructors
    Class Client3
        Public Shared Sub Main()
            Class1.Test()
            Class2.Test()
            '
            Console.ReadLine()
        End Sub
    End Class
End Namespace
Namespace SharedConstructors
    Class Client4
        Public Shared Sub Main()
            Class2.Test()
            '
            Console.ReadLine()
        End Sub
    End Class
End Namespace
Namespace Excercise1
    Class Client
        Public Shared Sub Main()
            Console.WriteLine(Calculation.GetSum(1, 2))
            Console.WriteLine(Calculation.GetProduct(3, 4))
            '
            Console.ReadLine()
        End Sub
    End Class
End Namespace
Namespace Excercise1
    Class Calculation
        Public Shared Function GetSum(ByVal value1 As Integer, _
                                      ByVal value2 As Integer) As Integer
            GetSum = value1 + value2
        End Function
        Public Shared Function GetProduct(ByVal value1 As Integer, _
                                          ByVal value2 As Integer) As Integer
            GetProduct = value1 * value2
        End Function
    End Class
End Namespace
Namespace Excercise2
    Class Client
        Public Shared Sub Main()
            Dim rectangle1 As Rectangle = New Rectangle(7, 5)
            Dim rectangle2 As Rectangle = New Rectangle(8, 4)
            '
            Console.WriteLine(rectangle1.ToString() = "7 by 5")
            Console.WriteLine(rectangle2.ToString() = "8 by 4")
            '
            Console.WriteLine(rectangle1.IsGreaterThan(rectangle2) = True)
            Console.WriteLine(rectangle2.IsGreaterThan(rectangle1) = False)
            '
            Console.WriteLine(Rectangle.Greatest(rectangle1, rectangle2) Is rectangle1)
            '
            Console.ReadLine()
        End Sub
    End Class
End Namespace
Namespace Excercise2
    Class Rectangle
        Public Sub New(ByVal height As Single, ByVal width As Single)
            Me.Height = height
            Me.Width = width
        End Sub
        Private m_Height As Single
        Public Property Height() As Single
            Get
                Height = m_Height
            End Get
            Set(ByVal value As Single)
                m_Height = value
            End Set
        End Property
        Private m_Width As Single
        Public Property Width() As Single
            Get
                Width = m_Width
            End Get
            Set(ByVal value As Single)
                m_Width = value
            End Set
        End Property
        Public ReadOnly Property Area() As Double
            Get
                Area = Height * Width
            End Get
        End Property
        Public Function IsGreaterThan(ByVal other As Rectangle) As Boolean
            If Me.Area > other.Area Then IsGreaterThan = True
        End Function
        Public Shared Function Greatest(ByVal rectangle1 As Rectangle, _
                                        ByVal rectangle2 As Rectangle) _
                                                                    As Rectangle
            Greatest = rectangle1
            If rectangle2.IsGreaterThan(rectangle1) Then Greatest = rectangle2
        End Function
        Public Overrides Function ToString() As String
            ToString = Height & " by " & Width
        End Function
    End Class
End Namespace
'Bezoek www.vbvoorbeelden.be voor meer Visual Basic voorbeelden.
'Copyright - De Wolf / vbvoorbeelden - 2003-2011 - Alle rechten voorbehouden.