visual basic 2010 broncode voorbeelden

Class Person
    Private m_Name As String
    Public Property Name() As String
        Get
            Name = m_Name
        End Get
        Set(ByVal value As String)
            m_Name = value
        End Set
    End Property
    Public Overrides Function ToString() As String
        ToString = Name
    End Function
End Class
Class LinkedList
    Public Class Node
        Private m_NextNode As Node
        Private m_Value As Object
        Public Sub New(ByVal value As Object)
            Me.Value = value
        End Sub
        Public Property NextNode() As Node
            Get
                NextNode = m_NextNode
            End Get
            Set(ByVal value As Node)
                m_NextNode = value
            End Set
        End Property
        Public Property Value() As Object
            Get
                Value = m_Value
            End Get
            Set(ByVal value As Object)
                m_Value = value
            End Set
        End Property
    End Class
    '
    Private m_Head As Node
    Public Property Head() As Node
        Get
            Head = m_Head
        End Get
        Set(ByVal value As Node)
            m_Head = value
        End Set
    End Property
    Public ReadOnly Property Count() As Integer
        Get
            Dim pointer As Node = Head
            Do Until pointer Is Nothing
                Count += 1
                pointer = pointer.NextNode
            Loop
        End Get
    End Property
    Public Sub Add(ByVal node As Node)
        If Head Is Nothing Then
            Head = node
        Else
            Dim pointer As Node = Head
            Do Until pointer.NextNode Is Nothing
                pointer = pointer.NextNode
            Loop
            pointer.NextNode = node
        End If
    End Sub
    Public Sub Insert(ByVal node As Node, ByVal beforeNode As Node)
        Dim previousNode As Node = getPreviousNode(beforeNode)
        If previousNode IsNot Nothing Then
            node.NextNode = previousNode.NextNode
            previousNode.NextNode = node
        Else
            If beforeNode Is Head Then
                node.NextNode = Head
                Head = node
            End If
        End If
    End Sub
    Private Function getPreviousNode(ByVal node As Node) As Node
        Dim pointer As Node = Head
        Do Until pointer Is Nothing OrElse pointer.NextNode Is node
            pointer = pointer.NextNode
        Loop
        getPreviousNode = pointer
    End Function
    Public Sub Remove(ByVal node As Node)
        Dim previousNode As Node = getPreviousNode(node)
        If previousNode IsNot Nothing Then
            previousNode.NextNode = node.NextNode
        Else
            If node Is Head Then
                Head = Head.NextNode
            End If
        End If
    End Sub
    Public Sub Clear()
        Head = Nothing
    End Sub
    Public Overrides Function ToString() As String
        Dim pointer As Node = Head
        Do Until pointer Is Nothing
            ToString &= pointer.Value.ToString() & " - "
            pointer = pointer.NextNode
        Loop
    End Function
End Class
Class Example
    Public Shared Sub Main()
        Dim linkedList1 As LinkedList = New LinkedList
        PrintLinkedList(linkedList1) ' "(0) : "
        '
        Dim node1 As LinkedList.Node = New LinkedList.Node(1)
        Dim node2 As LinkedList.Node = New LinkedList.Node(New System.Object)
        Dim node3 As LinkedList.Node = _
                       New LinkedList.Node(New Person With {.Name = "John Doe"})
        '
        linkedList1.Add(node1)
        linkedList1.Add(node2)
        linkedList1.Add(node3)
        PrintLinkedList(linkedList1)
        '
        linkedList1.Remove(node2)
        PrintLinkedList(linkedList1)
        '
        linkedList1.Insert(node2, node1)
        PrintLinkedList(linkedList1)
        '
        linkedList1.Clear()
        PrintLinkedList(linkedList1)
        '
        Console.ReadLine()
    End Sub
    Public Shared Sub PrintLinkedList(ByVal linkedList As LinkedList)
        Console.WriteLine("(" & linkedList.Count & ") : " & _
                          linkedList.ToString())
    End Sub
End Class

(0) :
(3) : 1 - System.Object - John Doe -
(2) : 1 - John Doe -
(3) : System.Object - 1 - John Doe -
(0) :