Visual Basic 2010 Imports Namespaces, Imports en Access Modifiers

home links
visual basic 2010 broncode voorbeelden

18.2. Imports

Dit artikel is gepubliceerd op zondag 31 juli 2011 op vbvoorbeelden, bezoek de website voor een recente versie van dit artikel of andere artikels.

In plaats van in een source-code document steeds naar de fully-qualified-identifier te verwijzen van een bepaald type, kan men ook bovenaan het source-code document ( boven de type definities ) een Imports statement opnemen.

Naast het keyword Imports staat steeds de fully-qualified-identifier van de namespace of klasse waarvan men op verkorte wijze naar de inhoud wenst te verwijzen.

ConsoleApplication1 is hier de root namespace-naam.

Visual Basic 2010 Broncode

Imports ConsoleApplication1.Persons
Imports ConsoleApplication1.Class1                                         ' (0)
Class Person ' type-1
    '...
End Class
Namespace Persons
    Class Person ' type-2
        '...
    End Class
    Class Student : Inherits Person
        '...
    End Class
End Namespace
Class Example1
    Public Shared Sub Main()
        Dim student1 As ConsoleApplication1.Persons.Student = _
                                  New ConsoleApplication1.Persons.Student  ' (1)
        Dim student2 As Persons.Student = New Persons.Student              ' (2)
        Dim student3 As Student = New Student                              ' (3)
        '
        Dim person1 As Person = New Person                                 ' (4)
        Dim person2 As Persons.Person = New Persons.Person                 ' (5)
        Dim person3 As ConsoleApplication1.Persons.Person = _
                               New ConsoleApplication1.Persons.Person      ' (6)
    End Sub
End Class

Download Visual Basic 2010 Broncode Download Visual C# Sourcecode

Door hier bovenaan de regel Imports ConsoleApplication1.Persons op te nemen, kan men op regel (3) op vereenvoudigde wijze de "type specifier" voor het type ConsoleApplication1.Persons.Student ( zoals gebruikt op regel (1) ) formuleren.

Let ervoor op dat in sommige situaties de type specifiers nog altijd "ambigue" kunnen zijn. Zo zal het opgenomen Imports statement geen nut hebben om op vereenvoudigde manier te verwijzen naar het type ConsoleApplication1.Persons.Person. Regel (4) creëert immers nog steeds een Person object van type-1.
Een meer absolute verwijzing ( zoals op regels (5) of (6) ) naar het type ConsoleApplication1.Persons.Person zal nog steeds nodig zijn om een Person object van type-2 te bekomen

Imports statements veranderen niets wezenlijk aan de programma-uitvoer, maar maken het enkel makkelijker type specifiers te formuleren.

Visual Studio : Men kan per source-code document Imports statements aanbrengen, of in Visual Studio kan men op project-niveau meerdere imports verwezenlijken.
Doordat bijvoorbeeld in een console-applicatie standaard de imports naar de System namespace vermeld wordt, hoeven we niet steeds de console aan te spreken met System.Console, maar volstaat een verwijzing Console.

Imports statements (0) kunnen ook gebruikt worden om op verkorte wijze te verwijzen naar class members van een klasse ( zoals op regel (1) ).

Visual Basic 2010 Broncode

Class Class1
    Public Shared Member1 As String = "Member1"
End Class
Class Example2
    Public Shared Sub Main()
        Console.WriteLine(Member1)                               ' "Member1" (1)
        Dim object1 As Class1 = New Class1                                 ' (2)
        '
        Console.ReadLine()
    End Sub
End Class

Download Visual Basic 2010 Broncode Download Visual C# Sourcecode

Wenst men echter een object te creëren van de klasse waarnaartoe verwezen werd in een Imports statement, dan zal men toch nog steeds minimaal de naam/identifier van de klasse moeten vermelden in de objectinitializer ( zoals op regel (2) ).

Imports statements die een fully-qualified-identifier van een klasse vermelden zijn dus enkel nuttig om op verkorte wijze naar de class members van die klasse te verwijzen.
Om redenen van leesbaarheid valt het overigens doorgaans af te raden deze werkwijze te hanteren.

Dit artikel is gepubliceerd op zondag 31 juli 2011 op vbvoorbeelden, bezoek de website voor een recente versie van dit artikel of andere artikels.

hoofdstuk	17. Enumeraties 18. Namespaces, Imports en Access Modifiers 19. Partial Namespaces, Classes en Methods
onderwerp	18.1. Namespaces 18.2. Imports 18.3. Default Access Modifiers
broncode	Download Imports.vb of Imports.cs
datum	laatst gewijzigd op dinsdag 23 september 2008, laatst gepubliceerd op zondag 31 juli 2011

visual basic 2010 broncode voorbeelden

18.2. Imports